set term pdfcairo enhanced font 'Times'  linewidth 20 square size 279cm,210cm

set output 'gnuplot-16-2_8129f.pdf'
nome='Lucas Alexandre Souza Rosa'



set multiplot

y0=0.85
set label  1 '{/*36{/Times-Italic Certificado}}'
set label  1  at screen 0.5, screen y0 center

y1=0.73
set label  2 '{/*22 Certifico que}'
set label  2 at screen 0.5, screen y1 center

set label  3 sprintf("{/*36{/Times-Italic %s}}", nome)
set label  3 at screen 0.5, screen y1-0.06 center

set label  4 '{/*22 concluiu o {/Times-bold curso de extensão em gnuplot} com duração de {/Times-bold 40 horas},}'
set label  4  at screen 0.5, screen y1-0.15 center

set label  5 '{/*22 ministrado pelo prof. {/Times-Italic Helton da Silva Gaspar} durante o segundo semestre de 2016}'
set label  5  at screen 0.5, screen y1-0.20 center

set label  6 '{/*22 na Universidade Federal de Santa Catarina, campus Joinville.}'
set label  6  at screen 0.5, screen y1-0.25 center

set label  7 '{/*22 Joinville, 25 de abril de 2017}'
set label  7 at screen 0.6, 0.38  left


y2=0.18
set label  8 '{/*16 prof. Helton da Silva Gaspar}'
set label  8 at screen 0.7, y2  left front

set label  9 sprintf("{/*12 Certificado digital: {/Mono http://helton.paginas.ufsc.br/files/2017/04/%s}}", 'gnuplot-16-2\_8129f.pdf' );
set label  9 at screen 0.93, 0.1  left right


cor_borda='grey50'


unset xtics;   # Remove tick-marks
unset ytics;   # Remove tick-marks
unset ztics;   # Remove tick-marks
unset border;  # Remove a borda


set origin 0.7,y2-0.11;# posição   da plotagem das bordas
set size 0.2, 0.3
set size ratio 0.5566
# plot 'sign.gif' binary filetype=gif with rgbimage


####################################################################################################
# Funções auxiliares 
mag2(x,y,z)=x*x+y*y+z*z
mag(x,y,z)=sqrt(mag2(x,y,z))


LG=10.0;       # Largura do G    
HG=3.0;        # Altura  do G

LU=0.4*LG;     # Largura do U e do N
HU=HG;         # Altura  do U e do N

S=0.2*LG;      # Espaçamento entre letras

# set origin 0.05,0.05;# posição   da plotagem das bordas
# set size   0.90,0.90;# dimensões da plotagem das bordas


set origin 0.01,0.02;# posição   da plotagem das bordas
set size   0.98,0.96;# dimensões da plotagem das bordas


set isosample 23 

## Marca d'água ###################################################################################
splot [-(a=4*pi):a][-a:a][-0.5:2.0] \
  cos(mag(x,y,0))*1./(0.8+mag(x,y,0))<0.8?cos(mag(x,y,0))*1./(0.8+mag(x,y,0)):1/0     notitle lc rgb '#ecd2f6',\
  cos(mag(x,y,0))*1./(0.9+mag(x,y,0))<0.8?1.6-cos(mag(x,y,0))*1./(0.8+mag(x,y,0)):1/0 notitle lc rgb '#cfede5'



## Bordas #########################################################################################
set parametric;# alterna modo de plotagem para fazer as bordas
dx=(LG+3*S+2*LU);#Espaçamento entre os GNU's da borda
do for [by=0:1] {
do for [bx=0:1] {
# bx=m;
# by=m;#1-m;

x=bx*(279);
y=(1-by)*210;

if ( bx==by ) {Nx=int(279/dx)}\
else          {Nx=int((210)/dx)}

jy=+(ix=1-bx-by);
jx=-(iy=by-bx);


set size ratio 210./279

plot [0:1][0:279][0:210]\
  for [ny=0:1] for [nx=ny:Nx] x+nx*dx*ix+(LG+S)*ny*ix+(LG*(1-t)       )*ix   -(HG+S)*ny*jx                   , nx*dx*iy+(LG+S)*ny*iy+(LG*(1-t)       )*iy     +y-(HG+S)*ny*jy                           notitle 'G' w l lw 2 lc rgb cor_borda,\
  for [ny=0:1] for [nx=ny:Nx] x+nx*dx*ix+(LG+S)*ny*ix                        -(HG+S)*ny*jx-(HG*t        )*jx , nx*dx*iy+(LG+S)*ny*iy+                          y-(HG+S)*ny*jy-(HG*t        )*jy         notitle 'G' w l lw 2 lc rgb cor_borda,\
  for [ny=0:1] for [nx=ny:Nx] x+nx*dx*ix+(LG+S)*ny*ix+(LG*t           )*ix   -(HG+S)*ny*jx-(HG          )*jx , nx*dx*iy+(LG+S)*ny*iy+(LG*t           )*iy     +y-(HG+S)*ny*jy-(HG          )*jy         notitle 'G' w l lw 2 lc rgb cor_borda,\
  for [ny=0:1] for [nx=ny:Nx] x+nx*dx*ix+(LG+S)*ny*ix+(LG             )*ix   -(HG+S)*ny*jx-(HG*(1-0.5*t))*jx , nx*dx*iy+(LG+S)*ny*iy+(LG             )*iy     +y-(HG+S)*ny*jy-(HG*(1-0.5*t))*jy         notitle 'G' w l lw 2 lc rgb cor_borda,\
  for [ny=0:1] for [nx=ny:Nx] x+nx*dx*ix+(LG+S)*ny*ix+(LG*(1-0.7*t)   )*ix   -(HG+S)*ny*jx-(0.5*HG      )*jx , nx*dx*iy+(LG+S)*ny*iy+(LG*(1-0.7*t)   )*iy     +y-(HG+S)*ny*jy-(0.5*HG      )*jy         notitle 'G' w l lw 2 lc rgb cor_borda,\
  for [ny=0:1] for [nx=ny:Nx] x+nx*dx*ix+(LG+S)*ny*ix+(LG+S           )*ix   -(HG+S)*ny*jx+(HU*(t-1)    )*jx , nx*dx*iy+(LG+S)*ny*iy+(LG+S           )*iy     +y-(HG+S)*ny*jy+(HU*(t-1)    )*jy         notitle 'N' w l lw 2 lc rgb cor_borda,\
  for [ny=0:1] for [nx=ny:Nx] x+nx*dx*ix+(LG+S)*ny*ix+(LG+S+LU*t      )*ix   -(HG+S)*ny*jx                   , nx*dx*iy+(LG+S)*ny*iy+(LG+S+LU*t      )*iy     +y-(HG+S)*ny*jy                           notitle 'N' w l lw 2 lc rgb cor_borda,\
  for [ny=0:1] for [nx=ny:Nx] x+nx*dx*ix+(LG+S)*ny*ix+(LG+S+LU        )*ix   -(HG+S)*ny*jx-(HU*t        )*jx , nx*dx*iy+(LG+S)*ny*iy+(LG+S+LU        )*iy     +y-(HG+S)*ny*jy-(HU*t        )*jy         notitle 'N' w l lw 2 lc rgb cor_borda,\
  for [ny=0:1] for [nx=ny:Nx] x+nx*dx*ix+(LG+S)*ny*ix+(LG+2*S+LU      )*ix   -(HG+S)*ny*jx+(HU*(t-1)    )*jx , nx*dx*iy+(LG+S)*ny*iy+(LG+2*S+LU      )*iy     +y-(HG+S)*ny*jy+(HU*(t-1)    )*jy         notitle 'N' w l lw 2 lc rgb cor_borda,\
  for [ny=0:1] for [nx=ny:Nx] x+nx*dx*ix+(LG+S)*ny*ix+(LG+2*S+LU*(1+t))*ix   -(HG+S)*ny*jx-(HU          )*jx , nx*dx*iy+(LG+S)*ny*iy+(LG+2*S+LU*(1+t))*iy     +y-(HG+S)*ny*jy-(HU          )*jy         notitle 'N' w l lw 2 lc rgb cor_borda,\
  for [ny=0:1] for [nx=ny:Nx] x+nx*dx*ix+(LG+S)*ny*ix+(LG+2*S+LU*2    )*ix   -(HG+S)*ny*jx-(HU*t        )*jx , nx*dx*iy+(LG+S)*ny*iy+(LG+2*S+LU*2    )*iy     +y-(HG+S)*ny*jy-(HU*t        )*jy         notitle 'N' w l lw 2 lc rgb cor_borda
  
}
}

## Brasão da UFSC #################################################################################
set origin 0.08,0.12;# posição   da plotagem das bordas
set size 0.2, 0.3
set size ratio 1.6788

#plot 'brasao_UFSC.gif' binary filetype=gif with rgbimage


unset multiplot
set output